/*
 * Copyright 2002-2008 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

package org.springframework.transaction.aspectj;

import org.springframework.transaction.annotation.AnnotationTransactionAttributeSource;
import org.springframework.transaction.annotation.Transactional;

/**
 * Concrete AspectJ transaction aspect using Spring Transactional annotation
 * for JDK 1.5+.
 * 
 * <p>When using this aspect, you must annotate the implementation class
 * (and/or methods within that class), <i>not the interface (if any) that
 * the class implements. AspectJ follows Java's rule that annotations on 
 * interfaces are <i>not inherited.
 *
 * <p>A @Transactional annotation on a class specifies the default transaction
 * semantics for the execution of any <b>public operation in the class.
 *
 * <p>A @Transactional annotation on a method within the class overrides the
 * default transaction semantics given by the class annotation (if present). 
 * Any method may be annotated (regardless of visibility).
 * Annotating non-public methods directly is the only way
 * to get transaction demarcation for the execution of such operations.
 *
 * @author Rod Johnson
 * @author Ramnivas Laddad
 * @author Adrian Colyer
 * @since 2.0
 * @see org.springframework.transaction.annotation.Transactional
 */
public aspect AnnotationTransactionAspect extends AbstractTransactionAspect {

	public AnnotationTransactionAspect() {
		super(new AnnotationTransactionAttributeSource(false));
	}

	/**
	 * Matches the execution of any public method in a type with the
	 * Transactional annotation, or any subtype of a type with the
	 * Transactional annotation.
	 */
	private pointcut executionOfAnyPublicMethodInAtTransactionalType() :
		execution(public * ((@Transactional *)+).*(..)) && @this(Transactional);

	/**
	 * Matches the execution of any method with the 
	 * Transactional annotation.
	 */
	private pointcut executionOfTransactionalMethod() :
		execution(* *(..)) && @annotation(Transactional);

	/**
	 * Definition of pointcut from super aspect - matched join points
	 * will have Spring transaction management applied.
	 */	
	protected pointcut transactionalMethodExecution(Object txObject) :
		(executionOfAnyPublicMethodInAtTransactionalType()
		 || executionOfTransactionalMethod() )
		 && this(txObject);

}